kitty added

.gitignore

@@ -1,2 +1,3 @@
 .session
-modules/chataigne/squashfs-root
+/nixos.qcow2
+/result

configs/common.nix

@@ -1,335 +0,0 @@
-{
-  config,
-  lib,
-  pkgs,
-  inputs,
-  ...
-}:
-
-{
-  imports = [
-    /etc/nixos/hardware-configuration.nix
-  ];
-
-  # Nix settings
-  ## Limit Cores on rebuild and enable Flakes
-  nix = {
-    registry = {
-      voidarc = {
-        from = {
-          id = "voidarc";
-          type = "indirect";
-        };
-        to = {
-          type = "git";
-          url = "https://git.voidarc.co.uk/voidarc/flakes.git";
-        };
-      };
-    };
-    settings = {
-      cores = 6;
-      download-buffer-size = 524288000;
-      experimental-features = [
-        "nix-command"
-        "flakes"
-      ];
-    };
-  };
-
-  ## Allow unfree packages and add pkgs.unstable
-  nixpkgs = {
-    config = {
-      allowUnfree = true;
-      packageOverrides = pkgs: {
-        unstable = import inputs.nixpkgs-unstable {
-          config = {
-            allowUnfree = true;
-          };
-        };
-      };
-    };
-  };
-
-  ## Optimise Nix store on rebuild and collect garbage as a service
-  nix.optimise.automatic = true;
-  nix.gc = {
-    automatic = true;
-    dates = "daily";
-    options = "--delete-older-than 5d";
-  };
-
-  # Bootloader theming and plymouth
-  boot = {
-    loader = {
-      timeout = 2;
-      efi = {
-        canTouchEfiVariables = true;
-      };
-      grub = {
-        efiSupport = true;
-        device = "nodev";
-        theme = pkgs.catppuccin-grub;
-      };
-    };
-    plymouth = {
-      enable = true;
-      theme = "catppuccin-mocha";
-      themePackages = with pkgs; [
-        # By default we would install all themes
-        (catppuccin-plymouth.override {
-          variant = "mocha";
-        })
-      ];
-    };
-  };
-
-  ## Use latest kernel
-  boot.kernelPackages = pkgs.linuxPackages_latest;
-
-  # Bluetooth and Networking
-  hardware.bluetooth.enable = true;
-  hardware.xpadneo.enable = true;
-
-  networking.networkmanager.enable = true;
-  networking.networkmanager.dns = "none";
-  networking.nameservers = [
-    "1.1.1.1"
-    "8.8.8.8"
-  ];
-
-  # Locale
-  time.timeZone = "Europe/London";
-  i18n.defaultLocale = "en_GB.UTF-8";
-  i18n.extraLocaleSettings = {
-    LC_ADDRESS = "en_GB.UTF-8";
-    LC_IDENTIFICATION = "en_GB.UTF-8";
-    LC_MEASUREMENT = "en_GB.UTF-8";
-    LC_MONETARY = "en_GB.UTF-8";
-    LC_NAME = "en_GB.UTF-8";
-    LC_NUMERIC = "en_GB.UTF-8";
-    LC_PAPER = "en_GB.UTF-8";
-    LC_TELEPHONE = "en_GB.UTF-8";
-    LC_TIME = "en_GB.UTF-8";
-  };
-
-  # Userspace Stuff
-  ## Keymap
-  services.xserver.xkb = {
-    layout = "gb";
-    variant = "";
-  };
-  console.keyMap = "uk";
-
-  ## Desktop
-  services.xserver.enable = true;
-  programs.hyprland = {
-    enable = true;
-    package = inputs.hyprland.packages.${pkgs.stdenv.hostPlatform.system}.default;
-  };
-  security.polkit.enable = true;
-
-  ## Audio Server
-  services.pulseaudio.enable = false;
-  security.rtkit.enable = true;
-  services.pipewire = {
-    enable = true;
-    alsa.enable = true;
-    alsa.support32Bit = true;
-    pulse.enable = true;
-    jack.enable = true;
-  };
-
-  # Local User
-  ## User config
-  users.users.user01 = {
-    isNormalUser = true;
-    shell = pkgs.zsh;
-    description = "user01";
-    extraGroups = [
-      "input"
-      "root"
-      "plugdev"
-      "bluetooth"
-      "networkmanager"
-      "docker"
-      "wheel"
-    ];
-    packages =
-      with pkgs;
-      let
-        input =
-          {
-            package,
-            output ? "default",
-          }:
-          inputs.${package}.packages.${pkgs.stdenv.hostPlatform.system}.${output};
-        wrap =
-          {
-            name,
-            pkg,
-            modules,
-          }:
-          pkgs.symlinkJoin {
-            inherit name;
-            paths = [ pkg ];
-            nativeBuildInputs = [ pkgs.makeWrapper ];
-            postBuild = ''
-              wrapProgram $out/bin/${name} \
-                --prefix PATH : ${pkgs.lib.makeBinPath modules}
-            '';
-          };
-      in
-      [
-        # Ricing
-        ## Desktop
-        bibata-cursors
-        catppuccin-gtk
-        unstable.waybar
-        hyprlock
-        dunst
-        wlogout
-        wpaperd
-        quickshell
-
-        ## Desktop Utilities
-        grimblast
-        gsettings-desktop-schemas
-        wl-clipboard
-        (wrap {
-          name = "otter-launcher";
-          pkg = (
-            input {
-              package = "otter-launcher";
-            }
-          );
-          modules = [
-            chafa
-            jq
-          ];
-        })
-        (input { package = "fsel"; })
-
-        # Terminal
-        ## Styling / Functionality
-        oh-my-posh
-        carapace
-        zsh-autocomplete
-        bat
-
-        ## Tools
-        lazygit
-        p7zip-rar
-        any-nix-shell
-        bluetui
-        fzf
-        ripgrep
-        wget
-        htop
-        playerctl
-        git
-        lsd
-        (input {
-          package = "doot";
-        })
-
-        ## Other CLI Apps
-        nodejs
-        fastfetch
-        opencode
-        tailscale
-        syncthing
-        jellyfin-tui
-
-        # Apps
-        ## Actual Useful Stuff
-        nemo
-        kitty
-        firefox
-        gotify-desktop
-        pavucontrol
-        mpv
-        input-remapper
-
-        ## Other Nonsense
-        tor-browser
-        techmino
-        prismlauncher
-        delfin
-      ];
-  };
-
-  ## Zsh
-  programs.zsh = {
-    enable = true;
-    enableCompletion = true;
-    enableBashCompletion = true;
-    autosuggestions.enable = true;
-    syntaxHighlighting.enable = true;
-    histSize = 10000;
-    ohMyZsh = {
-      enable = true;
-      plugins = [
-        "git"
-        "dirhistory"
-        "history"
-      ];
-    };
-  };
-  users.defaultUserShell = pkgs.zsh;
-
-  ## User programs
-  programs = {
-    dconf.enable = true;
-    xfconf.enable = true;
-    gdk-pixbuf.modulePackages = [ pkgs.librsvg ]; # For wlogout svgs
-  };
-
-  ## User Services
-  services = {
-    gvfs.enable = true;
-    input-remapper.enable = true;
-    tailscale.enable = true;
-    printing.enable = true;
-    upower.enable = true;
-    openssh.enable = true;
-    avahi.enable = true;
-  };
-
-  ## Fonts
-  fonts.packages = with pkgs; [
-    nerd-fonts.fira-mono
-  ];
-  fonts.fontconfig.defaultFonts.serif = [ "Fira Mono Nerd Font" ];
-
-  # System Packages
-  environment.systemPackages = with pkgs; [
-
-    # Utilities
-    inputs.nvim-wrapped.packages.${stdenv.hostPlatform.system}.default
-    vim
-    unzip
-    python315
-    usbutils
-    curlWithGnuTls
-
-    # System
-    mesa
-    vulkan-tools
-    gvfs
-    wayvnc
-    clang
-    xdg-desktop-portal
-    xdg-desktop-portal-hyprland
-    glib
-    gnutls
-    liblzf
-    librsvg
-    appimage-run
-    libnotify
-    gsettings-desktop-schemas
-  ];
-
-  # The comment
-  system.stateVersion = "25.05"; # Did you read the comment?
-
-}

configs/configuration-laptop.nix

@@ -1,53 +0,0 @@
-{
-  config,
-  lib,
-  pkgs,
-  inputs,
-  ...
-}:
-
-{
-  networking.hostName = "mobile02"; # Define your hostname.
-
-  # Opengl and vulkan
-  hardware.graphics = {
-    enable = true;
-    extraPackages = with pkgs; [
-      intel-vaapi-driver
-      libva-vdpau-driver
-    ];
-  };
-
-  services.displayManager.sddm = {
-    enable = true;
-    theme = "catppuccin-mocha-mauve";
-    package = pkgs.kdePackages.sddm;
-  };
-
-  environment.systemPackages = with pkgs; [
-    # Catppuccin sddm theme
-    (pkgs.catppuccin-sddm.override {
-      flavor = "mocha";
-      font = "Fira Mono Nerd Font";
-      fontSize = "11";
-      background = null;
-    })
-  ];
-
-  # Local User
-  users.users.user01 = {
-    extraGroups = [ ];
-    packages = with pkgs; [
-      # Ricing
-      inputs.way-edges.packages.${stdenv.hostPlatform.system}.way-edges
-      inputs.chataigne.packages.${stdenv.hostPlatform.system}.default
-
-      # Terminal
-      light
-      # Apps
-    ];
-  };
-
-  programs.steam.enable = true;
-
-}

configs/configuration-pc.nix

@@ -1,170 +0,0 @@
-{
-  config,
-  lib,
-  pkgs,
-  inputs,
-  ...
-}:
-
-{
-  networking.hostName = "HACKSTATION";
-
-  # Enable nix-ld to run unpatched binaries
-  programs.nix-ld.enable = true;
-  programs.nix-ld.libraries = with pkgs; [
-    stdenv.cc.cc
-    zlib
-    libusb1
-  ];
-
-  # Add Samsung USB udev rules
-  services.udev.extraRules = ''
-    SUBSYSTEM=="usb", ATTR{idVendor}=="04e8", MODE="0666", GROUP="plugdev"
-  '';
-
-  hardware.amdgpu.initrd.enable = true;
-
-  # Opengl and vulkan
-  hardware.graphics = {
-    enable = true;
-    extraPackages = with pkgs; [
-      libva-vdpau-driver
-      libvdpau-va-gl
-    ];
-    enable32Bit = true;
-  };
-
-  hardware.amdgpu.opencl.enable = true;
-
-  boot.kernelParams = [
-    "amdgpu.ppfeaturemask=0xffffffff"
-  ];
-
-  # Wake on Lan
-  networking.interfaces.enp5s0.wakeOnLan.enable = true;
-  networking.firewall.enable = false;
-
-  systemd.services.NetworkManager-wait-online.enable = false;
-
-  services.displayManager = {
-    autoLogin.enable = true;
-    autoLogin.user = "user01";
-    sddm = {
-      enable = true;
-    };
-  };
-
-  # Pipewire stuff
-  services.pipewire.extraConfig.pipewire."97-null-sink" = {
-    "context.objects" = [
-      {
-        factory = "adapter";
-        args = {
-          "factory.name" = "support.null-audio-sink";
-          "node.name" = "Null-Sink";
-          "node.description" = "Null Sink";
-          "media.class" = "Audio/Sink";
-          "audio.position" = "FL,FR";
-        };
-      }
-      {
-        factory = "adapter";
-        args = {
-          "factory.name" = "support.null-audio-sink";
-          "node.name" = "Null-Source";
-          "node.description" = "Null Source";
-          "media.class" = "Audio/Source";
-          "audio.position" = "FL,FR";
-        };
-      }
-    ];
-  };
-  services.pipewire.extraConfig.pipewire."98-virtual-mic" = {
-    "context.modules" = [
-      {
-        name = "libpipewire-module-loopback";
-        args = {
-          "audio.position" = "FL,FR";
-          "node.description" = "Mumble as Microphone";
-          "capture.props" = {
-            # Mumble's output node name.
-            "node.target" = "Mumble";
-            "node.passive" = true;
-          };
-          "playback.props" = {
-            "node.name" = "Virtual-Mumble-Microphone";
-            "media.class" = "Audio/Source";
-          };
-        };
-      }
-    ];
-  };
-
-  # Mumble server
-  services.murmur = {
-    enable = true;
-    bandwidth = 540000;
-    bonjour = true;
-    password = "mumblepass";
-    autobanTime = 0;
-  };
-
-  # Local User
-  users.users.user01 = {
-    extraGroups = [
-      "docker"
-    ];
-    packages = with pkgs; [
-      bottles
-      mumble
-      gajim
-      ferdium
-      wine64
-      delfin
-      docker
-      orca-slicer
-      ffmpeg
-      inputs.norgolith.packages.${pkgs.stdenv.hostPlatform.system}.default
-    ];
-  };
-
-  environment.systemPackages = [
-    inputs.sls-steam.packages.${pkgs.stdenv.hostPlatform.system}.wrapped
-  ];
-
-  programs.wshowkeys = {
-    enable = true;
-    package = inputs.wshowkeys.packages.${pkgs.stdenv.hostPlatform.system}.default;
-  };
-
-  programs.steam = {
-    enable = true;
-    extraCompatPackages = with pkgs; [
-      proton-ge-bin
-    ];
-    package = pkgs.steam.override {
-      extraEnv = {
-        LD_AUDIT = "${
-          inputs.sls-steam.packages.${pkgs.stdenv.hostPlatform.system}.sls-steam
-        }/library-inject.so:${
-          inputs.sls-steam.packages.${pkgs.stdenv.hostPlatform.system}.sls-steam
-        }/SLSsteam.so";
-      };
-    };
-  };
-
-  services.unbound = {
-    enable = true;
-  };
-
-  services.wivrn = {
-    enable = true;
-    package = pkgs.unstable.wivrn;
-    openFirewall = true;
-  };
-
-  virtualisation.docker = {
-    enable = true;
-    enableOnBoot = false;
-  };
-}

flake.nix

@@ -4,87 +4,11 @@
   inputs = {
     # System
     nixpkgs.url = "github:nixos/nixpkgs/nixos-26.05";
-    nixpkgs-unstable.url = "github:NixOS/nixpkgs/nixos-unstable";
-    nvim-wrapped = {
-      url = "git+file:///home/user01/.dotfiles/.config/nvim";
-    };
-    hyprland.url = "github:hyprwm/Hyprland";
 
-    # Apps
+    flake-parts.url = "github:hercules-ci/flake-parts";
-    sls-steam.url = "github:AceSLS/SLSsteam";
+    import-tree.url = "github:vic/import-tree";
-    chataigne.url = "./modules/chataigne";
+    wrappers.url = "github:BirdeeHub/nix-wrapper-modules";
-    norgolith = {
-      url = "github:NTBBloodbath/norgolith";
-      inputs.nixpkgs.follows = "nixpkgs";
-    };
-    wshowkeys = {
-      url = "github:voidarclabs/wshowkeys";
-      inputs.nixpkgs.follows = "nixpkgs";
-    };
-
-    # Utils
-    doot = {
-      url = "github:voidarclabs/nixos.doot";
-      inputs.nixpkgs.follows = "nixpkgs";
-    };
-    way-edges = {
-      url = "github:way-edges/way-edges";
-      inputs.nixpkgs.follows = "nixpkgs";
-    };
-    otter-launcher = {
-      url = "github:kuokuo123/otter-launcher";
-      inputs.nixpkgs.follows = "nixpkgs";
-    };
-    fsel = {
-      url = "github:Mjoyufull/fsel";
-      inputs.nixpkgs.follows = "nixpkgs";
-    };
-
-    # Davinci-resolve
-    mesa-davinci.url = "github:nixos/nixpkgs?ref=599ddd2b79331c1e6153e1659bdaab65d62c4c82";
-
-    omnisearch = {
-      url = "git+https://git.voidarc.co.uk/voidarc/omnisearch";
-      inputs.nixpkgs.follows = "nixpkgs";
-    };
   };
 
-  outputs =
+  outputs = inputs: inputs.flake-parts.lib.mkFlake {inherit inputs;} (inputs.import-tree ./modules);
-    {
-      self,
-      nixpkgs,
-      ...
-    }@inputs:
-    let
-      system = "x86_64-linux";
-
-      hardwareConfig = import /etc/nixos/hardware-configuration.nix;
-      common = import ./configs/common.nix;
-
-      mkSystem =
-        extraModules:
-        nixpkgs.lib.nixosSystem {
-          inherit system;
-          specialArgs = { inherit inputs; };
-          modules = [
-            common
-            hardwareConfig
-          ]
-          ++ extraModules;
-        };
-    in
-    {
-      nixosConfigurations = {
-        mobile02 = mkSystem [ ./configs/configuration-laptop.nix ];
-        hackstation = mkSystem [
-          ./configs/configuration-pc.nix
-          ./modules/davinci/davinci.nix
-          ./modules/i3/i3.nix
-          inputs.omnisearch.nixosModules.default
-          {
-            services.omnisearch.enable = true;
-          }
-        ];
-      };
-    };
 }

modules/chataigne/flake.lock

@@ -1,27 +0,0 @@
-{
-  "nodes": {
-    "nixpkgs": {
-      "locked": {
-        "lastModified": 1780952837,
-        "narHash": "sha256-Fwd1+spDtQ0hDyBwme6ufG3n4mY0UrjjFdYHv+G/Hds=",
-        "owner": "nixos",
-        "repo": "nixpkgs",
-        "rev": "e820eb4a444b46a19b2e03e8dfd2359439ff30fe",
-        "type": "github"
-      },
-      "original": {
-        "owner": "nixos",
-        "ref": "nixos-25.11",
-        "repo": "nixpkgs",
-        "type": "github"
-      }
-    },
-    "root": {
-      "inputs": {
-        "nixpkgs": "nixpkgs"
-      }
-    }
-  },
-  "root": "root",
-  "version": 7
-}

modules/chataigne/flake.nix

@@ -1,82 +0,0 @@
-{
-  description = "Local wrapper for Chataigne AppImage";
-
-  inputs = {
-    nixpkgs.url = "github:nixos/nixpkgs/nixos-25.11";
-  };
-
-  outputs =
-    { self, nixpkgs }:
-    let
-      system = "x86_64-linux";
-      pkgs = import nixpkgs { inherit system; };
-
-      # The libraries you requested
-      deps = with pkgs; [
-        curlFull
-        gnutls
-        libxrandr
-        alsa-lib
-        freetype
-        avahi
-        libglvnd
-        curl
-        SDL2
-        hidapi
-        libpulseaudio
-        lz4
-        openssl
-        libcap
-        libxcrypt
-        libgcrypt
-        libbsd
-        zlib
-        glib
-      ];
-
-      # Wrap the local AppImage file
-      chataigne-bin = pkgs.appimageTools.wrapType2 {
-        pname = "chataigne";
-        version = "1.10.3";
-        # This points to the file in the same directory as flake.nix
-        src = ./Chataigne-linux-x64-1.10.3.AppImage;
-        extraPkgs = pkgs: deps;
-      };
-
-      # Create the Desktop Entry
-      chataigne-desktop = pkgs.makeDesktopItem {
-        name = "chataigne";
-        exec = "chataigne";
-        icon = "chataigne";
-        comment = "Modular machine for art and technology";
-        desktopName = "Chataigne";
-        categories = [
-          "AudioVideo"
-          "Development"
-        ];
-      };
-    in
-    {
-      # packages.${system}.default = chataigne-bin;
-
-      devShells.${system}.default = pkgs.mkShell {
-        # Packages you want available in your shell
-        buildInputs = [
-          chataigne-bin
-        ];
-
-        # Environmental variables or shell hooks
-        shellHook = ''
-          echo "something"
-        '';
-      };
-      # This allows you to run 'nix run' or install it via system config
-      packages.${system}.default = pkgs.symlinkJoin {
-        name = "chataigne";
-        paths = [
-          chataigne-bin
-          chataigne-desktop
-        ];
-      };
-    };
-}

modules/davinci/davinci.nix

@@ -1,192 +0,0 @@
-# Tested on Davinci 20.2.2. It works for loading videos and exporting in H264/5 & AV1
-# Even if following this guide https://www.reddit.com/r/LinuxCrackSupport/comments/1nfqhld/davinci_resolve_studio_202_fix_linux_crack_guide/
-# nixpkgs rev used for this tests: 4652ba995a945108fb891191c1e910b9a6ed9064
-
-{ lib, inputs, ... }:
-let
-  mesa-good-pkg = inputs.mesa-davinci.legacyPackages.x86_64-linux.mesa;
-  pkgs = import (builtins.fetchTarball {
-    url = "https://github.com/NixOS/nixpkgs/archive/ec7c70d12ce2fc37cb92aff673dcdca89d187bae.tar.gz";
-  }) { config.allowUnfree = true; };
-  pkgs-pinned =
-    import
-      (builtins.fetchTarball {
-        url = "https://github.com/NixOS/nixpkgs/archive/497ee3c70707fd71b45c37d48ae1d45e79751047.tar.gz";
-      })
-      {
-        config = {
-          allowUnfree = true;
-        };
-      };
-
-  ffmpeg-encoder-plugin = pkgs.stdenv.mkDerivation (finalAttrs: {
-    pname = "ffmpeg-encoder-plugin";
-    version = "1.2.1";
-
-    src = pkgs.fetchFromGitHub {
-      owner = "EdvinNilsson";
-      repo = "ffmpeg_encoder_plugin";
-      rev = "v${finalAttrs.version}";
-      hash = "sha256-F4Q8YCXD5UldTwLbWK4nHacNPQ/B+4yLL96sq7xZurM=";
-    };
-
-    nativeBuildInputs = [ pkgs.cmake ];
-    buildInputs = [ pkgs.ffmpeg-full ];
-
-    installPhase = ''
-      mkdir -p $out
-      cp ffmpeg_encoder_plugin.dvcp $out/
-    '';
-  });
-
-  davinci-resolve-studio-cracked =
-    let
-      davinci-patched = pkgs-pinned.davinci-resolve-studio.davinci.overrideAttrs (old: {
-        # script based on https://www.reddit.com/r/LinuxCrackSupport/comments/1nfqhld/davinci_resolve_studio_202_fix_linux_crack_guide/
-        #
-        # Additionally, it will install ffmpeg_encoder_plugin to enable H264/5 & AV1 exports:
-        # https://github.com/EdvinNilsson/ffmpeg_encoder_plugin
-        #
-        # Note: $out IS /opt/resolve
-        postInstall = ''
-                    ${old.postInstall or ""}
-                    ${lib.getExe pkgs.perl} -pi -e 's/\x74\x11\xe8\x21\x23\x00\x00/\xeb\x11\xe8\x21\x23\x00\x00/g' $out/bin/resolve
-                    ${lib.getExe pkgs.perl} -pi -e 's/\x03\x00\x89\x45\xFC\x83\x7D\xFC\x00\x74\x11\x48\x8B\x45\xC8\x8B/\x03\x00\x89\x45\xFC\x83\x7D\xFC\x00\xEB\x11\x48\x8B\x45\xC8\x8B/' $out/bin/resolve
-                    ${lib.getExe pkgs.perl} -pi -e 's/\x74\x11\x48\x8B\x45\xC8\x8B\x55\xFC\x89\x50\x58\xB8\x00\x00\x00/\xEB\x11\x48\x8B\x45\xC8\x8B\x55\xFC\x89\x50\x58\xB8\x00\x00\x00/' $out/bin/resolve
-                    ${lib.getExe pkgs.perl} -pi -e 's/\x41\xb6\x01\x84\xc0\x0f\x84\xb0\x00\x00\x00\x48\x85\xdb\x74\x08\x45\x31\xf6\xe9\xa3\x00\x00\x00/\x41\xb6\x00\x84\xc0\x0f\x84\xb0\x00\x00\x00\x48\x85\xdb\x74\x08\x45\x31\xf6\xe9\xa3\x00\x00\x00/' $out/bin/resolve
-                    touch $out/.license/blackmagic.lic
-                    echo -e "LICENSE blackmagic davinciresolvestudio 999999 permanent uncounted\n  hostid=ANY issuer=CGP customer=CGP issued=28-dec-2023\n  akey=0000-0000-0000-0000 _ck=00 sig=\"00\"" > $out/.license/blackmagic.lic
-
-          					mkdir -p $out/IOPlugins/ffmpeg_encoder_plugin.dvcp.bundle/Contents/Linux-x86-64
-          					cp ${ffmpeg-encoder-plugin}/ffmpeg_encoder_plugin.dvcp $out/IOPlugins/ffmpeg_encoder_plugin.dvcp.bundle/Contents/Linux-x86-64/
-          					'';
-      });
-    in
-
-    # the following was copied from davinci's derivation from nixpkgs.
-    # if davinci updates, this should be updated too
-    # but remember to replace "davinci" with "davinci-patched"
-    pkgs.buildFHSEnv {
-      inherit (davinci-patched) pname version;
-
-      targetPkgs =
-        pkgs:
-        with pkgs;
-        [
-          alsa-lib
-          aprutil
-          bzip2
-          dbus
-          expat
-          fontconfig
-          freetype
-          glib
-          libGL
-          libGLU
-          libarchive
-          libcap
-          librsvg
-          libtool
-          libuuid
-          libxcrypt # provides libcrypt.so.1
-          libxkbcommon
-          nspr
-          ocl-icd
-          opencl-headers
-          python3
-          python3.pkgs.numpy
-          udev
-          xdg-utils # xdg-open needed to open URLs
-          libICE
-          libSM
-          libX11
-          libXcomposite
-          libXcursor
-          libXdamage
-          libXext
-          libXfixes
-          libXi
-          libXinerama
-          libXrandr
-          libXrender
-          libXt
-          libXtst
-          libXxf86vm
-          libxcb
-          xcbutil
-          xcbutilimage
-          xcbutilkeysyms
-          xcbutilrenderutil
-          xcbutilwm
-          xkeyboardconfig
-          zlib
-          ocl-icd
-          rocmPackages.clr.icd
-          libGL
-          libGLU
-        ]
-        ++ [
-          mesa-good-pkg
-          davinci-patched
-        ];
-
-      extraPreBwrapCmds = ''
-        mkdir -p ~/.local/share/DaVinciResolve/Extras || exit 1
-      '';
-
-      extraBwrapArgs = [
-        ''--bind "$HOME"/.local/share/DaVinciResolve/Extras ${davinci-patched}/Extras''
-      ];
-
-      runScript = "${lib.getExe pkgs.bash} ${pkgs.writeText "davinci-wrapper" ''
-          export QT_XKB_CONFIG_ROOT="${pkgs.xkeyboard_config}/share/X11/xkb"
-          export QT_PLUGIN_PATH="${davinci-patched}/libs/plugins:$QT_PLUGIN_PATH"
-          export LD_LIBRARY_PATH=$LD_LIBRARY_PATH:/usr/lib:/usr/lib32:${davinci-patched}/libs
-        	# Force Resolve to use X11 (via XWayland) to avoid Aquamarine/Hyprland conflicts
-          export QT_QPA_PLATFORM=xcb
-          export LD_LIBRARY_PATH=$LD_LIBRARY_PATH:${davinci-patched}/libs
-          
-          # Prevent Resolve from trying to talk to the Wayland socket directly
-          unset WAYLAND_DISPLAY
-          ${davinci-patched}/bin/resolve
-      ''}";
-
-      extraInstallCommands = ''
-        mkdir -p $out/share/applications $out/share/icons/hicolor/128x128/apps
-        ln -s ${davinci-patched}/share/applications/*.desktop $out/share/applications/
-        ln -s ${davinci-patched}/graphics/DV_Resolve.png $out/share/icons/hicolor/128x128/apps/davinci-resolve-studio.png
-      '';
-
-      passthru = {
-        inherit davinci-patched;
-        updateScript = lib.getExe (
-          pkgs.writeShellApplication {
-            name = "update-davinci-resolve";
-            runtimeInputs = [
-              pkgs.curl
-              pkgs.jq
-              pkgs.common-updater-scripts
-            ];
-            text = ''
-              set -o errexit
-              drv=pkgs/by-name/da/davinci-resolve/package.nix
-              currentVersion=${lib.escapeShellArg davinci-patched.version}
-              downloadsJSON="$(curl --fail --silent https://www.blackmagicdesign.com/api/support/us/downloads.json)"
-
-              latestLinuxVersion="$(echo "$downloadsJSON" | jq '[.downloads[] | select(.urls.Linux) | .urls.Linux[] | select(.downloadTitle | test("DaVinci Resolve")) | .downloadTitle]' | grep -oP 'DaVinci Resolve \K\d+\.\d+(\.\d+)?' | sort | tail -n 1)"
-              update-source-version davinci-resolve "$latestLinuxVersion" --source-key=davinci.src
-
-              # Since the standard and studio both use the same version we need to reset it before updating studio
-              sed -i -e "s/""$latestLinuxVersion""/""$currentVersion""/" "$drv"
-
-              latestStudioLinuxVersion="$(echo "$downloadsJSON" | jq '[.downloads[] | select(.urls.Linux) | .urls.Linux[] | select(.downloadTitle | test("DaVinci Resolve")) | .downloadTitle]' | grep -oP 'DaVinci Resolve Studio \K\d+\.\d+(\.\d+)?' | sort | tail -n 1)"
-              update-source-version davinci-resolve-studio "$latestStudioLinuxVersion" --source-key=davinci.src
-            '';
-          }
-        );
-      };
-    };
-in
-{
-  environment.systemPackages = [ davinci-resolve-studio-cracked ];
-}

modules/features/kitty/default.nix

@@ -0,0 +1,55 @@
+{
+  self,
+  inputs,
+  ...
+}: {
+  flake.nixosModules.kitty = {
+    pkgs,
+    lib,
+    ...
+  }: {
+    programs.kitty = {
+      enable = true;
+      package = self.packages.${pkgs.stdenv.hostPlatform.system}.kitty;
+    };
+  };
+  perSystem = {
+    pkgs,
+    lib,
+    self',
+    ...
+  }: {
+    packages.kitty = let
+      myFont = pkgs.nerd-fonts.fira-mono; # or any font-providing package
+      fontsConf = pkgs.makeFontsConf {
+        fontDirectories = [myFont];
+      };
+    in
+      inputs.wrappers.wrappers.kitty.wrap {
+        inherit pkgs;
+        environment = {
+          "FONTCONFIG_FILE" = "${fontsConf}";
+        };
+        font = {
+          name = "FiraMono Nerd Font";
+          size = 11;
+        };
+        settings = {
+          font_size = 11;
+          window_padding_width = 10;
+          background_opacity = 0.50;
+          confirm_os_window_close = 0;
+          enable_audio_bell = false;
+          cursor_trail = 1;
+          cursor_trail_start_threshold = 1;
+          cursor_trail_color = "#cba6f7";
+          cursor_shape = "beam";
+          allow_remote_control = true;
+        };
+        keybindings = {
+          "ctrl+backspace" = "send_text all \\x17";
+        };
+        themeFile = "Catppuccin-Mocha";
+      };
+  };
+}

modules/features/zsh/config.toml

@@ -0,0 +1,100 @@
+console_title_template = '{{ .Shell }} in {{ .Folder }}'
+version = 3
+final_space = true
+
+[secondary_prompt]
+  template = '❯❯ '
+  foreground = 'magenta'
+  background = 'transparent'
+
+[transient_prompt]
+  template = '❯ '
+  background = 'transparent'
+  foreground_templates = ['{{if gt .Code 0}}red{{end}}', '{{if eq .Code 0}}magenta{{end}}']
+
+[[blocks]]
+  type = 'prompt'
+  alignment = 'left'
+  newline = true
+
+[[blocks.segments]]
+type = 'text'
+style = 'plain'
+template = '''
+{{- if .Env.DEVSHELL_NAME -}}
+  {{- $parts := split "|" .Env.DEVSHELL_NAME -}}
+  {{- range $part := $parts -}}
+    {{- if $part -}}
+      {{- $sub := split "/" $part -}}
+      {{- if eq (len $sub) 2 -}}
+        <{{ index $sub "_1" }}>{{ index $sub "_0" }}</> <#7f849c>| </>
+      {{- end -}}
+    {{- end -}}
+  {{- end -}}
+{{- end -}}
+'''
+
+	[[blocks.segments]] # Python venv
+  type = 'text'
+  style = 'plain'
+  template = '{{ if .Env.VIRTUAL_ENV }}<yellow>🐍 venv</> <#7f849c>|</> {{ end }}'
+
+	[[blocks.segments]] # Nix shell indicator
+  type = 'text'
+  style = 'plain'
+  template = '{{ if and .Env.IN_NIX_SHELL (not .Env.DEVSHELL_NAME) }}<blue> nsh</> <#7f849c>|</> {{ end }}'
+
+  [[blocks.segments]]
+    template = '{{ .Path }}'
+    foreground = 'blue'
+    background = 'transparent'
+    type = 'path'
+    style = 'plain'
+
+    [blocks.segments.properties]
+      cache_duration = 'none'
+      style = 'full'
+
+  [[blocks.segments]]
+    template = ' {{ .HEAD }}{{ if or (.Working.Changed) (.Staging.Changed) }}<yellow> *</>{{ end }} <cyan>{{ if gt .Behind 0 }}󰁅{{ end }}{{ if gt .Ahead 0 }}{{ end }}</>'
+    foreground = 'green'
+    background = 'transparent'
+    type = 'git'
+    style = 'plain'
+
+    [blocks.segments.properties]
+      branch_icon = ''
+      cache_duration = 'none'
+      commit_icon = '@'
+      fetch_status = true
+
+[[blocks]]
+  type = 'rprompt'
+  overflow = 'hidden'
+
+  [[blocks.segments]]
+    template = '{{ .FormattedMs }}'
+    foreground = 'yellow'
+    background = 'transparent'
+    type = 'executiontime'
+    style = 'plain'
+
+    [blocks.segments.properties]
+      cache_duration = 'none'
+      threshold = 5000
+
+[[blocks]]
+  type = 'prompt'
+  alignment = 'left'
+  newline = true
+
+  [[blocks.segments]]
+    template = '❯'
+    background = 'transparent'
+    type = 'text'
+    style = 'plain'
+    foreground_templates = ['{{if gt .Code 0}}red{{end}}', '{{if eq .Code 0}}magenta{{end}}']
+
+    [blocks.segments.properties]
+      cache_duration = 'none'
+

modules/features/zsh/default.nix

@@ -0,0 +1,53 @@
+{
+  self,
+  inputs,
+  ...
+}: {
+  flake.nixosModules.zsh = {
+    pkgs,
+    lib,
+    ...
+  }: {
+    programs.zsh = {
+      enable = true;
+      package = self.packages.${pkgs.stdenv.hostPlatform.system}.myZsh;
+    };
+  };
+  perSystem = {
+    pkgs,
+    lib,
+    self',
+    ...
+  }: {
+    packages = {
+      myZsh = inputs.wrappers.wrappers.zsh.wrap {
+        inherit pkgs;
+        zshAliases = {
+          ls = lib.getExe pkgs.lsd;
+          cat = lib.getExe pkgs.bat;
+          lg = lib.getExe pkgs.lazygit;
+          man = "man -P \"${lib.getExe pkgs.bat} -p\"";
+          nsh = "nix-shell -p";
+        };
+        zshrc.content = ''
+          export CARAPACE_BRIDGES='zsh,fish,bash,inshellisense' # optional
+          zstyle ':completion:*' format $'\e[2;37mCompleting %d\e[m'
+          source <(${pkgs.carapace}/bin/carapace _carapace)
+          setopt NO_CASE_GLOB
+          zstyle ':completion:*' matcher-list 'm:{[:lower:]}={[:upper:]}' 'r:|[._-]=* r:|=*' 'l:|=* r:|=*'
+
+          export EDITOR=nvim
+
+          eval "$(${pkgs.devenv}/bin/devenv hook zsh)"
+          eval "$(${self.packages.${pkgs.host.stdenv.hostPlatform.system}.ohMyPosh}/bin/oh-my-posh init zsh)"
+
+          ${pkgs.any-nix-shell}/bin/any-nix-shell zsh --info-right | source /dev/stdin
+        '';
+      };
+      ohMyPosh = inputs.wrappers.wrappers.oh-my-posh.wrap {
+        inherit pkgs;
+        configFile = ./config.toml;
+      };
+    };
+  };
+}

modules/hosts/HACKSTATION/default.nix

@@ -0,0 +1,12 @@
+{
+  self,
+  inputs,
+  ...
+}: {
+  flake.nixosConfigurations.HACKSTATION = inputs.nixpkgs.lib.nixosSystem {
+    modules = with self.nixosModules; [
+      core
+      hackstationConfiguration
+    ];
+  };
+}

modules/hosts/HACKSTATION/hackstationConfiguration.nix

@@ -0,0 +1,9 @@
+{
+  self,
+  inputs,
+  ...
+}: {
+  flake.nixosModules.hackstationConfiguration = {pkgs, ...}: {
+    networking.hostName = "HACKSTATION";
+  };
+}

modules/i3/i3.nix

@@ -1,28 +0,0 @@
-{
-  config,
-  lib,
-  pkgs,
-  inputs,
-  ...
-}:
-{
-  services.libinput.enable = true;
-
-  services.displayManager.defaultSession = "hyprland";
-  services.xserver = {
-    enable = true;
-
-    desktopManager = {
-      xterm.enable = false;
-    };
-
-    windowManager.i3 = {
-      enable = true;
-      extraPackages = with pkgs; [
-        dmenu # application launcher most people use
-        i3status # gives you the default i3 status bar
-        xinit
-      ];
-    };
-  };
-}

modules/parts.nix

@@ -0,0 +1,10 @@
+{
+  config = {
+    systems = [
+      "x86_64-linux"
+      "x86_64-darwin"
+      "aarch64-linux"
+      "aarch64-darwin"
+    ];
+  };
+}

modules/system/core.nix

@@ -0,0 +1,23 @@
+{
+  self,
+  inputs,
+  ...
+}: {
+  flake.nixosModules.core = {
+    pkgs,
+    lib,
+    ...
+  }: let
+    modules = with self.nixosModules; [
+      userConfiguration
+    ];
+  in {
+    imports =
+      [
+        /etc/nixos/hardware-configuration.nix
+      ]
+      ++ modules;
+
+    programs.zsh.enable = true;
+  };
+}

modules/system/core/user.nix

@@ -0,0 +1,22 @@
+{
+  self,
+  inputs,
+  ...
+}: {
+  flake.nixosModules.userConfiguration = {
+    pkgs,
+    lib,
+    ...
+  }: {
+    users.users.user01 = {
+      isNormalUser = true;
+      initialPassword = "password";
+      shell = pkgs.zsh;
+      description = "user01";
+      extraGroups = [
+        "root"
+        "wheel"
+      ];
+    };
+  };
+}