{
  description = "Master flake for Voidarc nix config";

  inputs = {
    # System
    nixpkgs.url = "github:nixos/nixpkgs/nixos-25.11";
    nvim-wrapped = {
      url = "git+file:///home/user01/.dotfiles/.config/nvim";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # Apps
    sls-steam.url = "github:AceSLS/SLSsteam";
    chataigne.url = "./modules/chataigne";

    # Utils
    doot.url = "github:voidarclabs/nixos.doot";
    way-edges.url = "github:way-edges/way-edges";
    otter-launcher.url = "github:kuokuo123/otter-launcher";
    fsel.url = "github:Mjoyufull/fsel";

    # Davinci-resolve
    mesa-davinci.url = "github:nixos/nixpkgs?ref=599ddd2b79331c1e6153e1659bdaab65d62c4c82";
  };

  outputs =
    {
      self,
      nixpkgs,
      ...
    }@inputs:
    let
      system = "x86_64-linux";

      hardwareConfig = import /etc/nixos/hardware-configuration.nix;
      common = import ./configs/common.nix;

      mkSystem =
        extraModules:
        nixpkgs.lib.nixosSystem {
          inherit system;
          specialArgs = { inherit inputs; };
          modules = [
            common
            hardwareConfig
          ]
          ++ extraModules;
        };
    in
    {
      nixosConfigurations = {
        mobile02 = mkSystem [ ./configs/configuration-laptop.nix ];
        hackstation = mkSystem [
          ./configs/configuration-pc.nix
          ./modules/davinci/davinci.nix
          ./modules/i3/i3.nix
        ];
      };
    };
}